Matrix Orbital Corp

Code: Select all

        list p=16F877
	Title "USART Demo Program"
;
;This program runs on the PICDEM-2 demo board.
;In the Demo board, Port B is connected to 8 LEDs. 
;When the PIC16F877 receives a word of data from
;the USART, the value is displayed on the LEDs and
;is retransmitted to the host computer.
;
 include <P16F877.INC>
 __CONFIG _CP_OFF & _WDT_OFF & _XT_OSC & _PWRTE_ON & _LVP_OFF 
CBLOCK 0x20
COUNT, DELAY,DELAYTMP,			; delay function variables...

 ENDC
 
 
 DELAY_MILLI macro TIME
  movlw TIME
  movwf DELAY
  call DELAY_MS
  endm

DELAY_MICRO macro TIME
  movlw TIME
  movwf DELAY
  call DELAY_US
  endm

SEND macro CHAR
	movlw CHAR
	movwf TXREG
	DELAY_MILLI 5
	endm

GREET macro  
	SEND 'H'	;call send macro, pass it H
	SEND 'e'
	SEND 'l'
	SEND 'l'
	SEND 'o'
	endm

;
	org	00h		;Reset Vector
	goto	Start
;
	org	04h
	goto	IntVector

    org     05h		;Beginning of program EPROM
    
;----------------------------------------------------------------------------------------
; Subroutines
;----------------------------------------------------------------------------------------
DELAY_US					; busy wait of DELAY us
						; 200ns instruction period assumed
  nop						; (1)
  nop						; (2)
  decfsz DELAY,f				; test DELAY count (3)
    goto DELAY_US				; loop if not done (4,5)
  return					; gtfo (4,5)

DELAY_MS					; busy wait of DELAY ms
						; dependant upon DELAY_US being accurate
  movf DELAY,w
  movwf DELAYTMP				; save DELAY time
DELAY_MS_LOOP					; inner loop
  movlw 245					; load 245 (1)
  movwf DELAY					; into DELAY (2)
  call DELAY_US					; wait 245us (3-249)
  movlw 245					; load 245 (250)
  movwf DELAY					; into DELAY (251)
  call DELAY_US					; wait 245us (252-498)
  movlw 245					; load 245 (499)
  movwf DELAY					; into DELAY (500)
  call DELAY_US					; wait 245us (501-747)
  movlw 246					; load 246 (748)
  movwf DELAY					; into DELAY (749)
  call DELAY_US					; wait 246us (750-997)
  decfsz DELAYTMP,f				; test DELAYTMP count (998)
    goto DELAY_MS_LOOP				; loop if not done (999,1000)
  return					; gtfo (999,1000)

Start
    clrf    PORTB           ;Clear PORT_B output latches
	bsf		STATUS,RP0
	movlw   b'00000001'
	movwf   TRISB 		;Config PORT_B as all outputs
	movlw	b'00100000'	;Enable RCIF interrupt
	movwf	PIE1
	movlw	0Ch		;19200 baud @4MHz
	movwf	SPBRG
	movlw	b'10100100'	;Async, High baud rate
    movwf	TXSTA
	bcf	STATUS,RP0
	
	movlw	b'10010000'	;Enable continous reception
	movwf	RCSTA
	movlw	b'11000000'	;Enable global interrupts
	movwf	INTCON
 
    GREET	; greetings message
   
Loop
	goto	Loop ;wait for recieve interrupt

IntVector
	movlw	06h		;Mask out unwanted bits
	andwf	RCSTA,W		;Check for errors
	btfss	STATUS,Z	
	goto	RcvError	;Found error, flag it

	btfss	PIR1,5		;Check for data ready
	retfie			;Some other interrupt, exit
	
	movf	RCREG,W		;Get input data
	movwf	PORTB		;Display on LEDs
	movwf	TXREG		;Echo character back
    movlw	h'0D'
    movwf	TXREG
    movlw	h'0A'		;newline
	movwf	TXREG
	retfie	

RcvError
	bcf	RCSTA,4		;Clear reciever status
	bsf	RCSTA,4
	movlw	0FFh		;Light all LEDs
	movwf	PORTB		
	retfie
	
	end